proc import out=work.a 
datafile='c:\users\grego\documents\stat 706\GAGERR.txt'
replace;
run;

PROC MIXED DATA=A;
CLASS OPERATOR PART;
MODEL MEASURE=;
RANDOM OPERATOR|PART;
RUN;

PROC GLM DATA=A;
CLASS OPERATOR PART;
MODEL MEASURE=OPERATOR|PART;
RANDOM OPERATOR|PART/TEST; *No variance components;
RUN;

proc glimmix data=A;
class operator part;
model measure= / s; *solution for overall mean and random effects;
random operator|part / cl;  *confidence limits for each random effect;
covtest zerog; *Omnibus test for each variance component;
run;

/* Mixed Effects Model */
PROC GLM DATA=A;
CLASS OPERATOR PART;
MODEL MEASURE=OPERATOR|PART;
RANDOM PART OPERATOR*PART/TEST;
*This command is superfluous;
test h=operator e=operator*part;
RUN;

/* Generates a test of the fixed effect, but not the random effects */
PROC MIXED DATA=A;
CLASS OPERATOR PART;
MODEL MEASURE=OPERATOR;
RANDOM PART OPERATOR*PART/ALPHA=.05;
RUN;

*Omnibus test of random effects is possible here;
PROC glimmix data=a;
CLASS OPERATOR PART;
MODEL MEASURE=OPERATOR;
lsmeans operator/adj=tukey pdiff;
RANDOM PART operator*part/alpha=0.05;
RUN;