data nflteams;

*infile 'z:\My Documents\teaching\stat_517\sas_nfl_data.txt' firstobs=2;
FILENAME webpage URL 'http://people.stat.sc.edu/hitchcock/sas_nfl_data.txt';
INFILE webpage firstobs=2;
INPUT teamname $22. @29 year_of_origin 29-32 @35 Origin_type :$16. Conference $ 52-59 @62 Division :$5. @69 Timezone :$8.; 
RUN;

/* Customizing titles and footnotes */

TITLE JUSTIFY= LEFT COLOR=RED BCOLOR=BLUE HEIGHT=1cm 'NFL Teams and their Origins';
FOOTNOTE FONT=Courier ITALIC 'Includes Conference, Division, and Time Zone';

PROC PRINT data=nflteams;
run;
title;
footnote;

/* Customizing PROC PRINT output */

PROC PRINT data=nflteams STYLE(DATA) = {BACKGROUND=pink} STYLE(HEADER) = {BACKGROUND=GREEN FOREGROUND=WHITE};
TITLE COLOR=MAROON ITALIC 'NFL Teams and their Origins';
VAR teamname Origin_type Conference Division;
VAR Timezone / STYLE(DATA) = {FONT_STYLE = ITALIC};
ID year_of_origin;
run;


/* Creating Formats for Output */

PROC FORMAT; 
VALUE yearcol
LOW -< 1970 = 'blue'
1970 - HIGH = 'red';
run;
PROC FORMAT; 
VALUE $divcol
'East','West' = 'blue'
'South'= 'green'
'North' = 'red';
run;


PROC PRINT data=nflteams;
TITLE COLOR=AQUA ITALIC 'NFL Teams and their Origins';
VAR year_of_origin / STYLE = {FOREGROUND = yearcol.};
VAR teamname Origin_type Conference ;
VAR Division / STYLE = {BACKGROUND = $divcol. FOREGROUND=WHITE};
VAR Timezone;
run;