data fall08;
FILENAME webpage URL 'http://people.stat.sc.edu/grego/courses/stat704/Fall8.txt';
INFILE webpage DLM='09'X;
INPUT major :$34. degree :$15. class :$10. cltotgpa gender $ noobs;
run;

proc sql inobs=136;
create table original as select noobs, major, class, cltotgpa, gender
from fall08;
quit;

*Slide 4;

data everyevenrecord;
do obsnum=2 to 136 by 2;
   set original point=obsnum;
   output;
end;
stop;
run;

proc sql;
select * from everyevenrecord;
quit;

*Slide 6;

data everyevenrecord;
do obsnum=2 to totobs by 2;
   set original point=obsnum nobs=totobs;
   output;
end;
stop;
run;

*Slide 7;

data subset (drop=i samplesize);
samplesize=20;
do i=1 to samplesize;
  obsnum=ceil(ranuni(0)*totobs);
  set original point=obsnum nobs=totobs;
  output;
end;
stop;
run;

proc sort data=subset;
by noobs;
run;

proc sql;
select * from subset;
quit;

*Slide 9;
data subset (drop=i sampsize);
sampsize=50;
do i=1 to sampsize;
  obsnum=ceil(ranuni(0)*totobs);
  set original point=obsnum nobs=totobs;
  output;
end;
stop;
run;

proc sort data=subset;
by noobs;
run;

proc sql;
select * from subset;
quit;

*Slide 10;

data subset (drop=obsleft samplesize);
samplesize=20;
obsleft=totobs;
do while (samplesize>0);
  obsnum+1;
  if ranuni(0)<samplesize/obsleft then do;
    set original point=obsnum nobs=totobs;
    output;
    samplesize=samplesize-1;
  end;
  obsleft=obsleft-1;
end;
stop;
run;

proc sql;
select * from subset;
quit;